FinaleScriptの使い方

多くのFinaleScriptコマンドは、FinaleScriptプラグインに設定されているグローバルオプションを参照します。スクリプトを実行する前に、FinaleScriptオプションが目的のスクリプト動作に従って設定されているか確認してください。

〔プラグイン〕メニューの〔FinaleScript〕から〔オプション〕を選択します。〔FinaleScript－オプション〕ダイアログボックスが表示されます。
すでにFinaleScriptパレットが表示されている場合は、オプションボタンをクリックします。
目的のスクリプト動作に応じて各オプションを選択または選択解除します。
〔OK〕をクリックします。

FinaleScriptのスクリプトを実行するには

〔プラグイン〕メニューの〔FinaleScript〕から〔FinaleScriptパレット〕を選択します。FinaleScriptパレットが表示されます。
実行するスクリプトを選択します。
スクリプトの実行方法を選択します。
- スクリプトを表示も編集もせずにすぐに実行するには、〔再生〕ボタンをクリックするか、スクリプトを右クリックまたはCONTROL＋クリックして〔実行〕を選択します。
- スクリプトを表示、編集してから実行する場合は、〔編集〕 ボタンをクリックします（またはスクリプトをダブルクリックします）。〔FinaleScript－編集〕ダイアログボックスが表示されます。必要な編集を加えてから〔スクリプトの実行〕をクリックします。
スクリプトが実行され、各コマンドに対応するメッセージがFinaleScriptパレットに表示されます。
スクリプト実行を途中で停止するには、〔停止〕ボタンをクリックします。

スクリプト実行後にレポートを表示するには

スクリプトを実行するたびにFinaleScriptレポートが作成されます。このレポートには、コマンドの成功／失敗、処理対象のフォルダ名、サブフォルダ名などの情報が記録されています。

FinaleScriptパレットの〔レポート〕ボタンをクリックします。〔FinaleScript－レポート〕ダイアログボックスが表示されます。
レポートの情報を別の場所で利用するには、〔クリップボードにコピー〕をクリックします。
お使いのテキストエディタを開き、〔編集〕>〔貼り付け〕を選択します（またはCOMMAND＋Vを押します）。
〔閉じる〕をクリックします。

FinaleScriptのスクリプトを新規作成するには

スクリプトを新規作成する前に、下記の「FinaleScriptの構造」とFinaleScriptコマンドリファレンスをお読みください。

スクリプトを新規作成する代わりに、既存のスクリプトを複製し編集することもできます。その場合は、FinaleScriptパレットで〔選択したスクリプトの複製〕ボタンをクリックします（または、スクリプトを右クリックまたはCONTROL＋クリックして〔複製〕を選択します）。

〔プラグイン〕メニューの〔FinaleScript〕から〔FinaleScriptパレット〕を選択します。FinaleScriptパレットが表示されます。
新規スクリプトの保存先を指定する場合は、フォルダを選択します。特にフォルダを指定しなければ、ルートのFinaleScriptフォルダに保存されます。
〔新規〕ボタンをクリックします（または、スクリプトリストウィンドウで右クリックまたはCONTROL＋クリックして〔新規スクリプトの挿入〕を選択します）。指定したフォルダに「名称未設定スクリプト」が表示されます。フォルダを指定していない場合は、FinaleScriptパレットのリストの一番上に「名称未設定スクリプト」が表示されます。

既存のFinaleScriptスクリプトを編集するには

スクリプトを編集する前に、下記の「FinaleScriptの構造」とFinaleScriptコマンドリファレンスをお読みください。

スクリプトを編集せずに既存のスクリプトをそのまま複製して使用することもできます。その場合は、FinaleScriptパレットで〔選択したスクリプトの複製〕ボタンをクリックします（または、スクリプトを右クリックまたはCONTROL＋クリックして〔複製〕を選択します）。

〔プラグイン〕メニューの〔FinaleScript〕から〔FinaleScriptパレット〕を選択します。FinaleScriptパレットが表示されます。
編集するスクリプトを選択して、〔編集〕ボタンをクリックします（またはスクリプトをダブルクリックします）。〔FinaleScript－編集〕ダイアログボックスが表示されます。
スクリプトを右クリックまたはCONTROL＋クリックして〔編集〕を選択してもかまいません。
編集ウィンドウで必要な変更を加えます。
- 編集ウィンドウにコマンドを入力します。入力すると同時に、自動カラー表示機能に従って文字列がカラー表示され、スクリプト文字列の機能に応じて色分けして表示されます。
  自動カラー表示機能について
  FinaleScriptの編集ウィンドウには自動カラー表示機能が備わっています。テキストを入力するとFinaleScriptの機能ごとに自動的に色分けされて表示され、入力ミスの発見に役立ちます。関連トピック FinaleScriptの使い方 - FinaleScriptの構造もご参照ください。
  - 緑…コマンド
  - 紫…属性
  - 青…数字
  - オレンジ…ストリング（”　”囲み）
  - 赤…フォント名（ [　]囲み）
  - 薄いグレー…コメント
  - 濃いグレー…FinaleScriptに認識されない文字列
- 〔スクリプトの名前〕テキストボックスにスクリプト名を編集します。
- 〔プラグイン〕>〔FinaleScript〕サブメニューにスクリプト名を表示させたい場合は、〔メニューに表示〕を選択します。
- スクリプトにショートカットキーを割り当てる場合は、〔ショートカットキーを使用〕を選択します。
スクリプトを記述しながら、定期的に〔保存〕をクリックして記述内容を保存するようにしてください。
〔保存して閉じる〕をクリックします。

スクリプトにショートカットキーを割り当てるには

〔FinaleScript－ショートカット定義〕ダイアログボックスを開きます。
- 〔FinaleScript－編集〕ダイアログボックスでスクリプトを表示している場合は、〔ショートカットキーを使用〕の近くの〔選択〕をクリックします。
- FinaleScriptパレットを表示している場合は、スクリプト名を右クリックまたはCONTROL＋クリックして〔キーボード・ショートカットの定義〕を選択します。
ショートカットキーの編集オプションを選択します。
- キーの組み合わせをコンピュータのキーボードで実際に押します。キーの組み合わせがダイアログボックスに表示されます。
- 〔候補を表示〕をクリックすると、使用可能なショートカットキーが表示されます。
- 〔使用しない〕をクリックすると、定義済みのショートカットキーが削除されます。
変更を保存するには〔OK〕をクリックします。変更を破棄するには〔キャンセル〕をクリックします。

FinaleScriptメニューにスクリプト名を表示するには

〔プラグイン〕メニューの〔FinaleScript〕から〔FinaleScriptパレット〕を選択します。FinaleScriptパレットが表示されます。
編集するスクリプトを選択して、〔編集〕ボタンをクリックします（またはスクリプトをダブルクリックします）。〔FinaleScript－編集〕ダイアログボックスが表示されます。
スクリプトを右クリックまたはCONTROL＋クリックして〔編集〕を選択してもかまいません。
〔メニューに表示〕を選択します。
〔保存して閉じる〕をクリックします。〔プラグイン〕>〔FinaleScript〕サブメニューにスクリプト名が表示されます。

スクリプトの構成を管理するには

個々のスクリプトはXMLファイルです。Finale以外のプログラムでスクリプトを管理するには、FinaleのUserフォルダにある「FinaleScript」ディレクトリに移動してください（Finaleインストール先フォルダの詳細を参照）。

スクリプトやフォルダを削除しても、実際はコンピュータのゴミ箱に移動しているので、（ゴミ箱を空にしない限り）元に戻すことができます。

〔プラグイン〕メニューの〔FinaleScript〕から〔FinaleScriptパレット〕を選択します。FinaleScriptパレットが表示されます。
スクリプトを個別に管理するには、対象スクリプトを選択してから動作を選択します。
- スクリプトの名前を変更するには、スクリプト名を右クリックまたはCONTROL＋クリックして〔名称の変更〕を選択します。〔FinaleScript－名称変更〕ダイアログボックスに新しいスクリプト名を入力して、〔OK〕をクリックします。
- スクリプトの複製を作成するには、〔選択したスクリプトの複製〕ボタンをクリックします（またはスクリプト名を右クリックまたはCONTROL＋クリックして〔複製〕を選択します）。
- スクリプトを別のフォルダに移動するには、移動先フォルダまでスクリプトをドラッグします。
- スクリプトを削除するには、〔削除〕ボタンをクリックして（または、スクリプト名を右クリックまたはCONTROL＋クリックしてから〔削除〕を選択して）、確認の警告メッセージに対して〔はい〕をクリックします。
スクリプトをフォルダ単位で管理するには、対象フォルダを選択してから動作を選択します。
- フォルダを作成するには、〔新規フォルダ作成〕ボタンをクリックします（または、スクリプトリストウィンドウで右クリックまたはCONTROL＋クリックして〔新規フォルダの挿入〕を選択します）。
- フォルダの名前を変更するには、フォルダ名を右クリックまたはCONTROL＋クリックして〔名称の変更〕を選択します。〔FinaleScript－名称変更〕ダイアログボックスに新しいフォルダ名を入力して、〔OK〕をクリックします。
- フォルダを別のフォルダに移動するには、移動先フォルダまでフォルダをドラッグします。
- フォルダを削除するには、〔削除〕ボタンをクリックして、確認の警告メッセージに対して〔はい〕をクリックします。

スクリプトを他のFinaleユーザーと共有するには

個々のスクリプトはXMLファイルです。他のファイルと同様に、いくつかの方法（電子メール、FTPなど）でスクリプトを共有できます。

FinaleScriptパレットでスクリプトを作成、保存して、Finaleを閉じます。
Finderで、Finale Userフォルダの「FinaleScript」ディレクトリに移動します（Finaleインストール先フォルダの詳細を参照）。
「FinaleScript」ディレクトリは、FinaleScriptパレットのフォルダ構造と同じように構成されています。
目的のフォルダを見つけます。スクリプトのファイル名は〔FinaleScript－編集〕ダイアログボックスの〔スクリプトの名前〕に表示される名前と基本的に同一ですが、スペースが削除され、すべて小文字で表示されています。
スクリプトのコピーを作成し、見つけやすい場所（「マイドキュメント」フォルダ、デスクトップなど）にペーストしてもかまいません。
このファイルを任意の方法で相手先に送信します。

コマンド

スクリプトの各行に記述できるコマンドは1つだけです。また、各キーワード（パラメータを含む）をスペースで区切る必要があります。例を見てみましょう。

create staff

この例は、create staffという最もシンプルなコマンドです。create、staffというキーワードで構成されています。このコマンドが指示していることは、既存の組段の下に単一の新規五線を追加して、その新規五線にすべてのデフォルト値（ト音記号、名称未設定の五線名など）を割り当てることです。このコマンドにいくつかパラメータを追加したものが下記の例です。

create grand staff "Calliope"

grandという属性により、五線が2本作成され、上の五線にはト音記号、下の五線にはヘ音記号が付きます。さらに、「Calliope」というグループ名が作成され、このグループに大譜表括弧が追加されます。この動作は、スコア・マネージャーで大譜表楽器（ピアノなど）を追加するのとまったく同じです。

上記の例では2つのパラメータを追加しています。大譜表を作成するgrand属性と、五線名Calliopeを設定する"Calliope"という文字列です。この例は、FinaleScriptの判読しやすさをよく表しています。すなわち、FinaleScriptでは、単一コマンドを構成する複数のキーワードを任意の順に並べることができます。途中にパラメータを挿入してもかまいません。このような特徴がなければ、コマンド行はcreate staff grand "Calliope"のようになり、読みやすさが低下します。構文に柔軟性があるので、意味的にも格段に理解しやすくなります。

さらに独創的にしたコマンドが次の例です。

create 2 bass staves "Trombone" "Tbn."

このコマンドは、2本の独立した五線を作成し、それぞれへ音記号を配置し、正式五線名「Trombone」と省略五線名「Tbn」を設定するように指示しています。この例では、FinaleScriptの読みやすさの別の特徴である「同意語」（後述）を表しています。すなわち、staffの同意語としてstavesが使われています。この特徴がなければcreate staff 2 bass "Trombone" "Tbn."となり、上記と同様に読みやすさが低下することになります。

パラメータ

上記の例にあるように、パラメータは、コマンドに具体的な修飾情報を与える働きをします。下記の4種類のパラメータがあります。

この4種類のパラメータ以外にも、Finaleの内部的アーキテクチャを処理するパラメータがいくつかありますが、下記の4種類でほぼすべての状況に対応できます。

数値　変数（num1, num2）は、通常、ファイル内の特定の要素（小節、レイヤー、ページなど）を指定する数値です。何らかの計測単位で表す数値の場合、デフォルトでは、現在選択している計測単位が参照されますが、数値の後ろに計測単位属性を付けることができます（in、cm、picasなど）。数値は区切り文字を必要としません。
文字列　変数(string1, string2)は、通常、以下のいずれかの項目を指定する英数字値です。
- ファイル内の要素の名前（五線名など）
- テキストフィールドの内容（タイトル、作曲者など）
- Finaleのユーザーインタフェース項目の名前（ダイアログボックス名など）
文字列は二重引用符で区切ります。
フォント　変数（font1, font2）は、文字列の検索/置換時などでフォントの名前を指定する英数字値です。フォントは角括弧で区切ります。
属性　コマンドを構成するキーワードと同様に、コマンドを修飾したり、コマンドの実行作業を変更したりする所定の用語が存在します。属性はあらかじめ定義されているので、区切り文字を必要としません。

パラメータが任意か必須かは、コマンドによって異なります。上記の例では、bassというパラメータは任意です。create staffというコマンドだけでも成立しますが、bass属性を付加することにより、「ヘ音記号の付いた五線を作成する」と、より具体的になります。これに対して、下記の例では1、2というパラメータは必須です。これらのパラメータがなければ、下記コマンドは意味を成しません。

move layer 1 to 2

パラメータを付加する結果、まったく違ったタスクを実行することになる場合もあります。例えば、下記コマンドは〔選択〕ツールを選択します。

select

これに対して、下記コマンドは、〔五線〕ツールを選択して、「Horn in F」という名前の五線を選択します。

select "Horn in F"

留意すべきことは、多くの場合、楽譜のどの部分を選択しているかによってコマンドの動作が異なることです。さらに、選択範囲に適用される場合もあれば、何も選択しなければ楽譜全体に適用される場合もあります。パラメータも、コマンドの動作を修飾する働きをするので、コマンドと同様に選択箇所によって動作が異なります。

同意語

FinaleScriptは、スクリプトを瞬時に理解できるように設計されています。このため、FinaleScriptには様々な同意語（同じ意味の代替語）が含まれています。任意の同意語を使って同一タスクを実行できます。例えば、以下の4つのどのコマンドも、選択範囲内の入力項目を削除します（〔編集〕>〔すべての項目を消去〕を実行）。

clear
reset
delete music
remove music

同意語には下記の3種類があります。

コマンドの同意語　多くの場合、コマンド全体を同意語に置き換えることができます。上の例では、一単語のコマンドであるclearの同意語として、2単語のコマンドdelete musicを使用しています。
個々のキーワードの同意語　コマンドを構成する個々の単語を同意語に置き換えることができます。上の例では、resetというキーワードはclearの同意語であり、removeというキーワードはdeleteの同意語です。

属性の同意語　コマンドを構成する定義済みの単語を同意語に置き換えることもできます。多くの場合、属性の同意語を使用すると、コマンドの明確さが低下します。例えば、以下の4つのコマンドはすべて、楽譜の3小節目から最終小節までを選択します。

select measure 3 to end
select measure 3 to bottom
select measure 3 end
select measure 3 0

2番目のコマンドのbottomはendの有効な同意語ですが、endと比べて明確さに欠けます。3番目のコマンドでは、toというキーワードが削除されています。この省略は有効です（このコマンドの文脈では、toは実際の機能を持たないため）が、選択範囲が不明確になっています。4番目のコマンドの場合、FinaleScriptの側では0を「楽譜の末尾まで」と理解しますが、一見してこの構文を認識できるユーザーは少ないはずです。このような理由から、先頭のコマンドが最善の選択肢です。簡潔さの点ではベストではありませんが、誤解を招く余地が最も少ない分かりやすいコマンドです。

計測単位属性の同意語

計測単位	同意語
EVPUS	`evpu`, `evpus`
ポイント	`pt`, `pts`, `point`, `points`
スペース	`s`, `sp`, `space`, `spaces`
パイカ	`pica`, `picas`
センチメートル	`cm`, `cent`, `centimeter`, `centimeters`
インチ	`i`, `in`, `inch`, `inches`

計測単位についての詳細は、計測単位をご覧ください。

FinaleScriptコマンドリファレンスに、各コマンドで使用できる同意語の一覧があります。

スクリプトにコメントを付記しておけば、作成者以外の人もスクリプトを的確に理解できるようになります。スクリプトを知るための手掛かりをコメントに記載してください。すなわち、重要情報を指摘し、任意の指示事項を示します。あるいは、各行や各セクションの動作を明確にするだけでもかまいません。

一行のみの単独のコメント、またはコマンドの後ろに記載するコメントは、次のように直前にスラッシュを2つ（//）付けてください。

// 選択範囲をF#メジャーに移調 key f# major

key f# major // 選択範囲をF#メジャーに移調

複数行のコメントを入力する場合は、次のように/*と*/で囲みます。

                        
                            /* 移調後の調に応じてこのスクリプトを編集する
    音階:
        長調
        短調
    主音:
        c
        c#
        db
        d
        d#
        ...
        a#
        bb
        b
*/
key c major

ヒント: 単一行を右クリックまたはCONTROL＋クリックして〔コメント表示/非表示〕を選択することにより、コメントの表示/非表示を簡単に切り替えることができます。

Finaleユーザーインタフェースの操作

主要ツール、メニュー内の各種機能、個々のファイル設定等をコマンドで指定できるだけでなく、Finaleユーザーインタフェースのほぼすべての要素を直接スクリプトに指定することもできます。

近くの項目名

厳密に言えば、FinaleScripはnearを有効なキーワードとして認識しないので、nearを使用する必要はありません。必要なのは、ラベル（画面上の表示名）を含む文字列だけです。それでも、読みやすくするためnearを使用することが推奨されます。

ダイアログボックス内の項目にラベルが付いていない場合（テキストボックスなど）や、複数の項目に同じラベルが付いている場合（〔フォント指定〕ボタンなど）があります。このようなときは、「near＋文字列」の形にしてください。

                                
                                    staff tool
menu item "五線の属性"
button "設定" //最初に見つかった設定ボタンを選択
button "設定" near "特殊な符頭" //対象ボタンを明確にする

メニュー項目と同様に、ショートカット文字を使って簡潔にすることができます。

                                
                                    document options
list "音符/休符"
button "選択" near "休符キャ*" //ショートカット文字を組み合わせる

複数のテキストボックスが縦横に並んでいる場合、ラベルはいっそう不明確になります。フィールド間を移動するにはtabを使用してください。

                                
                                    select all
menu item "指定する拍子に従って再連結"
button "複合拍子"
type 2 near "１小節内の拍数"
tab
type 8
tab
type 3
tab
type 8
button ok
button ok

ラジオボタン

ラジオボタンは、互いに排他的なオプション群で使用します。

                                
                                    document options
list "反復記号"
select radio button "最上段の五線のみ"

タブ

ダイアログボックスが複数のタブに分かれ、論理的カテゴリに従って設定が分類されている場合があります。タブを切り替えるにはselect tabを使います。

                                
                                    expression tool
double click
list "その他"
button "その他の発想記号*"
type "play second time only" near "注記"
select tab "playback"
select ポップアップ メニュー "ベロシティ" near "タイプ"
type 0 near "絶対値で指定"
check "指定回時のみ有効"
type 1 near "指定回時のみ有効"
button ok
button "配置"

スライダー

実例をご覧ください。

                                
                                    menu item "オーディオ設定"
move slider "マイクレベル" 110

Expect (to)

特定の項目が使用可能になるまでFinaleScriptに待機させるには、任意のユーザーインタフェースコマンドとexpect属性を組み合わせます。

ブロックしているダイアログボックスを無視して先に進むことはできません。

                                
                                    menu item "ファイル/エクスポート/オーディオファイル"
expect button save

テキストボックス（typeとraw）

ダイアログボックスにあるテキストボックスに文字を入力するには、typeを使います。

                                
                                    menu item "小節番号：範囲の編集"
button "delete"
button "add"
type 1 near "範囲"
type 999 near "小節目まで"
uncheck "小節番号を段頭*"
check "小節間隔"
type 5 near "小節間隔"
type 5 near "表示開始小節"
check "囲み図形" near "小節間隔"
button ok

raw属性と修飾キーを組み合わせて、このキーを type文字列の個々の文字に適用できます。

以前は、フォント選択などアクセス不能なMacリストのリスト項目の選択でもrawが使われていました（例：type raw "petrucci」）。

type raw command "ac" //COMMAND＋A、COMMAND＋Cに相当

また、rawがなければアクセス不能なフィールドに文字を入力するときにも使用できます。以下に例を示します。テキスト・ツールを使って作成したテキストフレーム：

                                
                                    text tool
double click
type raw "Copyright "
menu item "著作権*" //著作権記号を挿入
type raw command "v"

〔発想記号の設計－メイン〕ダイアログボックスの〔文字〕フィールド：

                                
                                    expression tool
double click
list "その他"
button "その他の発想記号*"
type raw "release the penguins"
type "penguin release" near "注記"
button ok
button "配置"

〔テキスト編集〕ウィンドウ（グループ名、五線名など）、〔テキスト〕ツールの〔テキスト編集〕ウィンドウ、〔歌詞〕ウィンドウの書式設定文字のフィールド：

                                
                                    menu item "スコア・マネージャー"
button "正式五線名"
type raw "Clarinet in B"
type raw command shift "f" //フラットを挿入
button ok

重要：テキストフィールドにフォーカスが当たっていなければrawは機能しないので、ご注意ください。例えば、同じ行にrawとnear属性を組み合わせることはできません。

ウィンドウとダイアログボックス

開いているダイアログボックスまたはドキュメントウィンドウに切り替えるには、select window（またはselect dialog box）を使います。対象のダイアログボックスはモードレスでなければなりません。モードレスとは、開いたダイアログボックスを閉じなくてもFinaleの別の場所をクリックして操作できるダイアログボックスのことです（ほとんどのダイアログボックスはモードレスではありません）。

                                
                                    select window "スコア・マネージャー"
tab "ファイル情報"
type "Fredric Marc Bunbury" near "編曲者"
select window "ページ・マージン編集"
type 1.5 near "下"
type 1 near "適用するページの範囲"
button "適用"

一括処理

FinaleScriptの最もパワフルな面は、複数のファイルに複数のコマンドを自動で適用できることです。このタスクを「一括処理」といいます。Finaleに現在開いている全ファイルや、コンピュータに作成された特定のフォルダ内の全ファイルを対象に処理することができます。

特定のフォルダのファイルを対象に処理する

開いているファイルの処理と同様に、フォルダを対象に処理する意図を示してから、ファイルに適用するコマンドを指定します。スクリプトの先頭近くに下記コマンドのどちらかを挿入してください。

batch process folder batch process folder and subfolders

一括処理の入出力フォルダは、FinaleScriptのsaveコマンド（およびパラメータ）にのみ適用されます。グラフィック、オーディオファイル、MusicXML等のエクスポートには適用されません。

さらに、一括処理元と一括処理先のフォルダを指定する必要があります。一括処理元/処理先フォルダの指定方法は3つあります。

スクリプトに正確なパスを指定する

batch process source folder "/Users/main/Desktop/Music" batch process destination folder "Mac HD:Users:main:Desktop:Music:Converted"

ユーザーにフォルダを指定するよう求める

ask source folder ask destination folder

〔FinaleScript－オプション〕でフォルダを選択してからスクリプトを実行する

スクリプトにフォルダのパスを指定するのは簡単です。〔Finale－編集〕ダイアログボックス内を右クリックまたはCONTROL＋クリックして〔パスの挿入〕を選択し、フォルダを選択を求めるダイアログボックスでフォルダを選択して、〔OK〕をクリックするだけです。選択したフォルダのパスが二重引用符で囲まれてスクリプトに挿入されます。

ヒント: Macでスクリプトにパスを挿入する場合は、POSIX、HFS、Windowsのパススタイルを使用できます。

簡単なスクリプト／計測単位の使用例

unitsexample.xml

                        
                            /*計測単位の一括設定はUnitコマンドを使用。各行で個別に指定することも可能。*/

unit evpus
staffline thickness 6
page format 21x29.7 cm
//現在行のみcmがunitコマンドに優先
beam thickness 24
//staffline thickness .02 inch

このスクリプトはコメントで始まっています。
先頭コマンドunitの後ろに属性evpusを付けることにより、全体の計測単位をEVPUEVPU（ENIGMA Virtual Page Units）とは、楽譜のサイズやスペーシングを計算するのに便利なFinaleの計測単位です。1インチが288 EVPU、1スペースが24 EVPUに相当します。Finaleでは、インチ、センチメートル、ポイント、スペースなど、様々な計測単位に変換しながら作業することができます。に設定します。
2行目はコマンドthicknessを属性stafflineで修飾し、ファイル内のすべての五線の線幅を6 EVPUに設定しています。なお、属性はコマンドの前後どちらに位置してもかまいません。
次に、page formatコマンドを使ってページサイズを横21 cm、縦29.7 cmに設定しています。ここでは、キーワードcmが先頭の一括指定単位unitより優先します。
この動作が一行コメントに書かれています。
beam thicknessコマンドにより、連桁の太さを24 EVPUに一括設定しています。
最後のコメント区切り文字（//）は、一般に「コメントアウト」と呼ばれる第二のコメント機能（プログラムの実行対象から外すこと）を表しています。スラッシュがなければ有効なthicknessコマンドであるため、3行目と同様に、（この行では）線幅が.02 inchに一括設定されることになります。しかし、このスクリプトの作成者はこのコマンドを（少なくとも一時的に）「コメントアウト」しているので、FinaleScriptの動作対象から除外され、単にコメントとして認識されます。

ページサイズ設定／ページサイズをTabloidに設定

setpagesizetotabloid.xml

                        
                            //batch process folder
//process all open

page format tabloid
//resize pages to 75%
//resize systems to 80%
//staff height = 82 evpus
reorganize layout
respace all
message "ファイルメニューのページ設定で忘れずにページサイズを設定してください。"

使いやすくするため、このスクリプトは先頭に2つの処理コマンドを置いています。現在はコメントアウトされていますが、簡単にコマンドに切り替えて実行できます。
このスクリプトの実質的コマンドは、次の行のpage formatとtabloid属性です。
後続のコメントアウトされた3つのコマンドは、各種楽譜要素を拡大縮小するオプションです。有用なプリセット値が用意されています。
reorganize layoutは、小節のロックを解除してレイアウトを更新します。respaceは、音符のスペーシングを実行します。
messageは、印刷の前に適切なページサイズを選択すべきことを知らせるメッセージをユーザーに表示します。

その他／見開き用のページ番号

addbookstylepagenumbers.xml

                        
                            //このスクリプトを実行する際には、マウスカーソルをページの左上に置いておく必要があります。
//ショートカットキーを利用すると便利でしょう。

text tool
double click
menu item"ページ番号"
menu item "フレーム属性"
dropdown "適用するページ範囲" near "割り付け先"
type 2 near "から"
type 0 near "→横"
type "48evpus" near "↑縦"
check "右ページの配置を使用"
dropdown "右揃え" near "水平位置"
type "48evpus" near "↑縦"
click OK

先頭のコメントは、2行目のdouble clickコマンドが任意のマウスカーソル位置で発生するので、マウスカーソルをページの空白部分に置くようユーザーに伝えています。
テキスト・ツールが選択され、ページ上のダブルクリックによりテキストフレームが作成され、〔文字〕>〔挿入〕>〔ページ番号〕によりページ番号が挿入されます。
〔フレーム属性〕ダイアログボックスが開き、後続の6つのコマンドによりダイアログボックスの設定が変更されて、〔OK〕がクリックされます。

コンバート／混声四部からピアノ譜へ変換

satbtopiano.xml

                        
                            //このスクリプトにより、SATBの混声四部譜（あるいはその他の４パートの楽譜）
//からピアノコンデンス譜を作成することができます。

//process folder
//process all open docs
work on layer 1
add piano staves "Piano"
select staff 2
copy
select staff 5
paste
move layer 1 to 2
//delete lyrics
select staff 1
copy
select staff 5
paste
//delete lyrics
select staff 4
copy
select staff 6
paste
move layer 1 to 2
//delete lyrics
select staff 3
copy
select staff 6
paste
//delete lyrics

//オプション:
Staff tool
select staves 1 to 4
menu item "五線を削除して再配置"

show all layers

select staff 1
Staff Attributes
Uncheck "省略の記譜法"
Hit "Ok"
select staff 2
Staff Attributes
Uncheck "省略の記譜法"
Hit "Ok"

//save and append "piano"
//close

このスクリプトの長さ自体が、複雑なタスクをFinaleScriptで簡単に自動化できることをよく表しています。先頭コメントのあと、2つの処理コマンドがコメントアウトされ、簡便にオン/オフ可能になっています。
楽譜の一番下に、正式五線名「Piano」の大譜表が作成されます。
直前にあるwork on layer 1コマンドにより、次のセクションで五線をコピーしても、既存レイヤーは上書きされません。
4本の既存五線のそれぞれに対して、4つのコマンド群で処理します。
- 2番目の五線（SATBのアルト）は、大譜表のト音記号五線にコピーされ、レイヤー2に移動します。コメントアウトされているオプションのdelete lyricsは、後続の3つのコマンド群にも記述されています。
- 1番目の五線（ソプラノ）は、大譜表のト音記号五線にコピーされます（レイヤー1）。
- 4番目の五線（バス）は、大譜表のヘ音記号五線にコピーされて、レイヤー2に移動します。
- 3番目の五線（テノール）は、大譜表のト音記号五線にコピーされます（レイヤー1）。
元の4本の五線が削除され、大譜表が再配置されます（コメントに「オプション」とあるので、これらの行はコメントアウトしてもかまいません）。
大譜表の個々の五線で省略の記譜法がオフにされるので、〔書類〕メニューの〔編集中のレイヤーのみ表示〕の選択を解除します。
便宜上、ファイルを閉じる処理（保存してファイルを閉じる）が記述されています。

一括処理／画像ファイルへ一括変換

batchsaveasgraphic.xml

                        
                            Batch Process Folder
//Process all open docs

Graphics tool
Menu item "ページのグラフィック出力"

Popup "TIFF"
//Popup "PICT"
//Popup "EPS"
//Popup "PDF"

Check "すべて"
Check "以下のファイル名から自動作成"
Type 1200 near "解像度"

//Check "フォントを含める"
//Check "透過属性を持たせる"

Press "OK"
//expect to return	//PDF作成時
Close

End

このスクリプトは一括処理用なので、最初からbatch process folderコマンドが有効になっています。処理対象に応じて、代わりにprocess all open docsを選択してもかまいません。
〔グラフィック〕ツールが選択され、〔グラフィック〕メニューの〔ページのグラフィック出力〕が選択されます。
〔選択範囲（ページ）のグラフィック出力〕ダイアログボックスでいくつか設定されます。
- 4つのファイル形式が選択可能になっています。
- 全ページが出力されます。
- 「[ファイル名]#」形式に従ってファイル名が設定されます。
- 解像度が1200dpiに設定されます。
- PostScript出力の場合、〔フォントを含める〕と〔透過属性を持たせる〕を選択可能です。
ダイアログボックスが閉じてファイルも閉じます。
コメントアウトされているexpect to returnは、PDF出力の場合に必要です。

複数のコマンドを組み合わせたスクリプトを記述するには

あらかじめプランを立てる。スクリプトの記述を始める前に、スクリプトで具体的に何を実現したいかを明確にしてください。目標が明確でない限り、タスクの実行に必要とされるコマンドを特定することができません。スクリプトが複雑化する場合は、推奨されるFinaleファイル入力順序を考慮する必要もあります。
FinaleScriptパレットのコマンド入力を利用して、ダミーファイルで個々のコマンドを試してみてください。FinaleScriptパレットの〔コマンド入力〕の真上にファイル名が表示されるので、コマンドが適用されるファイルを容易に確認できます。
空のスクリプトを作成する。スクリプトに分かりやすい名前を付け、必要に応じてカテゴリ別フォルダに配置してください。対象スクリプトを頻繁に使用する予定であれば（複数ファイルの一括処理など）、ショートカットキーを割り当てるかFinaleScriptメニューに表示することを検討してください。
必要な機能の一部を実行するスクリプトが作成済みであれば、複製して別名を付け、必要な変更を加えることもできます。
コマンドと属性を入力する。入力すると同時に、自動カラー表示機能に従って文字列がカラー表示され、スクリプト文字列の機能に応じて色分けして表示されます。この自動フォーマット機能をご活用ください。入力した単語がFinaleScriptの語彙に含まれているか、一行に複数のコマンドを記述していないかなどを確認できます。
自動カラー表示機能について
FinaleScriptの編集ウィンドウには自動カラー表示機能が備わっています。テキストを入力するとFinaleScriptの機能ごとに自動的に色分けされて表示され、入力ミスの発見に役立ちます。関連トピック FinaleScriptの使い方 - FinaleScriptの構造もご参照ください。
- 緑…コマンド
- 紫…属性
- 青…数字
- オレンジ…ストリング（”　”囲み）
- 赤…フォント名（ [　]囲み）
- 薄いグレー…コメント
- 濃いグレー…FinaleScriptに認識されない文字列
入力しながらカラー表示を確認するようにしてください。1文字のタイプミスでも、スクリプトの動作が大幅に変わったり停止することがあります。
コメントを多用する。FinaleScriptは読みやすく作られていますが、長く複雑なスクリプトはすぐに判読不能になります。思慮に富んだコメントは構造を明確にし、最初の段階でスクリプトを記述しやすくする上で大いに役立ちます。作成者だけでなく、スクリプトの利用者に対しても同じことが言えます。
スクリプトの実行前に、変更可能または変更が必要なファイルパス等のパラメータ（またはスクリプトの一部分全体）を明示する際、コメントを使うと特に便利です。
作成したスクリプトをダミーファイルでテストする。特にこの点が重要です。一般に、作成直後のスクリプトには誤りがあると考えてください。スクリプトの対象ファイルに似た記譜内容を持つダミーファイルを作成し、このダミーファイルでスクリプトを実行します。
結果を分析してください。問題がなければ準備が整ったことになります。しかし、多くの場合はスクリプトの微調整が必要です。現在のアプローチを一から考え直す必要がある場合もあります。コマンドが動作しないときはスペルミスも確認してください。
ファイルのバックアップを作成してから試用する。実際のファイルでスクリプトを実行する前に、ファイルのバックアップコピーを作成してください。これにより、不測の事態が発生してもファイルを元に戻すことができます。スクリプトが問題なく動作すれば成功です。失敗したり、何らかの理由で操作の取り消しができない場合は、元のファイルを使って再試行できます。
FinaleScriptを存分に活用してください。

FinaleScriptの使い方

FinaleScriptとは

共通の手順

FinaleScriptのスクリプトを記述する

FinaleScriptの構造

スクリプト実例

失敗しないスクリプトを作成するために